Workplace Effectiveness: Dealing with Change/Workplace Effectiveness: Dealing with Change.iso/pc/Assess.Dxr/Internal_291_reactions-bulletin board code.ls

Text File | 1998-04-24 | 6.5 KB | 250 lines

global gMasterData, gFirstCardSp, gTempArt, gCardLocL, gCardsMoved, gBoardScore, gFlashTime

on startReactions
  go("reaction")
  goNarrator(gMasterData, "15")
  setUserArea(gMasterData, #reactions1)
end

on boardSetup
  puppetTransition(1, 6)
  go(label("reaction") + 2)
  goNarrator(gMasterData, "16")
  set gFirstCardSp to 7
  set gTempArt to 48
  set gCardsMoved to []
  set gBoardScore to 0
  set gFlashTime to the ticks
  getSpriteLocs()
  setPuppetState([7, 32], #c, 1)
  setPuppetState([44, gTempArt], #n, 1)
  setHandCursor(#on, [7, 8, 9, 10, 11, 12, 13, 14, 15, 16, 17, 18, 19, 20, 21, 22, 23, 24, 25, 26, 27, 28, 29, 30, 31, 32])
end

on boardExit
  setPuppetState([7, 32], #c, 0)
  setPuppetState([3, 44, gTempArt], #n, 0)
  setHandCursor(#off, [7, 8, 9, 10, 11, 12, 13, 14, 15, 16, 17, 18, 19, 20, 21, 22, 23, 24, 25, 26, 27, 28, 29, 30, 31, 32])
  puppetSound(0)
end

on getSpriteLocs
  set gCardLocL to [:]
  repeat with sNum = gFirstCardSp to gFirstCardSp + 25
    addProp(gCardLocL, sNum, point(the locH of sprite sNum, the locV of sprite sNum))
  end repeat
  return gCardLocL
end

on moveCard
  set xsprite to the clickOn
  set moveMember to the member of sprite xsprite
  set the member of sprite gTempArt to moveMember
  set the loc of sprite xsprite to point(-999, -999)
  repeat while the mouseDown
    set the loc of sprite gTempArt to point(the mouseH, the mouseV)
    updateStage()
  end repeat
  EvalTarget(xsprite)
end

on EvalTarget xsprite
  if rollOver(4) then
    newLocation(xsprite)
  else
    PutBack(xsprite)
  end if
end

on newLocation xsprite
  if (count(gCardsMoved) < 10) or (getPos(gCardsMoved, xsprite) <> 0) then
    setItDown(xsprite)
  else
    PutBack(xsprite)
  end if
end

on setItDown xsprite
  puppetSound("thingset")
  set the loc of sprite xsprite to point(the mouseH, the mouseV)
  set the loc of sprite gTempArt to point(-999, -999)
  updateStage()
  if getPos(gCardsMoved, xsprite) = 0 then
    add(gCardsMoved, xsprite)
    scoreCard(#add, xsprite)
  end if
end

on PutBack xsprite
  puppetSound("swoosh")
  set vOrigLoc to getaProp(gCardLocL, xsprite)
  set the loc of sprite xsprite to vOrigLoc
  set the loc of sprite gTempArt to point(-999, -999)
  set listPos to getPos(gCardsMoved, xsprite)
  if listPos <> 0 then
    deleteAt(gCardsMoved, listPos)
    scoreCard(#subtract, xsprite)
  end if
  updateStage()
end

on scoreCard scoreMode, xsprite
  case xsprite of
    gFirstCardSp:
      set thisScore to 5
    (gFirstCardSp + 1):
      set thisScore to 10
    (gFirstCardSp + 2):
      set thisScore to 5
    (gFirstCardSp + 3):
      set thisScore to -10
    (gFirstCardSp + 4):
      set thisScore to 10
    (gFirstCardSp + 5):
      set thisScore to -10
    (gFirstCardSp + 6):
      set thisScore to 10
    (gFirstCardSp + 7):
      set thisScore to 0
    (gFirstCardSp + 8):
      set thisScore to -10
    (gFirstCardSp + 9):
      set thisScore to -10
    (gFirstCardSp + 10):
      set thisScore to 0
    (gFirstCardSp + 11):
      set thisScore to 10
    (gFirstCardSp + 12):
      set thisScore to 10
    (gFirstCardSp + 13):
      set thisScore to 10
    (gFirstCardSp + 14):
      set thisScore to 0
    (gFirstCardSp + 15):
      set thisScore to 0
    (gFirstCardSp + 16):
      set thisScore to 10
    (gFirstCardSp + 17):
      set thisScore to 0
    (gFirstCardSp + 18):
      set thisScore to -5
    (gFirstCardSp + 19):
      set thisScore to 10
    (gFirstCardSp + 20):
      set thisScore to -10
    (gFirstCardSp + 21):
      set thisScore to -10
    (gFirstCardSp + 22):
      set thisScore to 0
    (gFirstCardSp + 23):
      set thisScore to -10
    (gFirstCardSp + 24):
      set thisScore to -10
    (gFirstCardSp + 25):
      set thisScore to 10
    otherwise:
      set thisScore to 0
  end case
  case scoreMode of
    #add:
      set gBoardScore to gBoardScore + thisScore
    #subtract:
      set gBoardScore to gBoardScore - thisScore
  end case
end

on cardsFinished
  if count(gCardsMoved) < 10 then
    alert("Please select and move a total of ten cards to the bulletin board on the right.")
  else
    repeat with X = gFirstCardSp to gFirstCardSp + 25
      if getPos(gCardsMoved, X) = 0 then
        set the loc of sprite X to point(-999, -999)
        next repeat
      end if
      nothing()
    end repeat
    puppetSprite(44, 0)
    go("meter")
  end if
end

on setMeter
  global checkMarks1
  go(label("meter2"))
  setUserArea(gMasterData, #reactions2)
  puppetSound("twing.aif")
  if getaProp(checkMarks1, #reactions) = 0 then
    setaProp(checkMarks1, #reactions, 1)
  end if
  set needleSprite to 3
  puppetSprite(needleSprite, 1)
  case 1 of
    (gBoardScore >= 40):
      set the loc of sprite needleSprite to point(295, 184)
    (gBoardScore <= -40):
      set the loc of sprite needleSprite to point(295, 340)
    otherwise:
      set vLoc to 262 - integer(gBoardScore * (78 / 40.0))
      set the loc of sprite needleSprite to point(295, vLoc)
  end case
  updateStage()
end

on reSetCards
  puppetSprite(3, 0)
  repeat with X = gFirstCardSp to gFirstCardSp + 25
    if getPos(gCardsMoved, X) = 0 then
      set the loc of sprite X to getProp(gCardLocL, X)
      next repeat
    end if
    nothing()
  end repeat
  go(label("reaction") + 3)
  setUserArea(gMasterData, #reactions1)
  puppetSprite(44, 1)
end

on checkFlasher
  if count(gCardsMoved) = 10 then
    set vNewTime to the ticks
    set vDoneSprite to 44
    if vNewTime > (gFlashTime + 30) then
      set vThisName to the name of member the member of sprite vDoneSprite
      case vThisName of
        "YR done":
          set the member of sprite vDoneSprite to member "YR done flash"
        "YR done flash":
          set the member of sprite vDoneSprite to member "YR done"
      end case
      set gFlashTime to the ticks
    end if
  end if
end

on flashButton thisSprite
  set vNewTime to the ticks
  if vNewTime > (gFlashTime + 45) then
    set castMember to the member of sprite thisSprite
    set Castname to the name of member castMember
    set castNum to the castLibNum of member castMember
    if the puppet of sprite thisSprite then
      set the member of sprite thisSprite to castMember
      updateStage()
      puppetSprite(thisSprite, 0)
    else
      puppetSound("ding.aif")
      puppetSprite(thisSprite, 1)
      set the member of sprite thisSprite to member (Castname && "flash") of castLib castNum
      updateStage()
    end if
    set gFlashTime to the ticks
  end if
end

on getScoreMeterPos score
  set vLoc to 262 - integer(score * (78 / 40.0))
  set the loc of sprite 3 to point(295, vLoc)
  updateStage()
end